This tool works like PasteNoodles - it will post text from your clipboard to an online text file, and return the URL into your clipboard, for each pasting. But this pastes to my site, and copy-pasta.com is down. :)

If you keep this tool in your QuickLaunch tray, you can paste text online very quickly. ;)

Since the [url=http://kpaste.kristopherw.us/]KPaste / Freefile site[/url] does not allow anonymous postings, the KPaste tool will ask for your username and password the first time it is run.
(You can register [url=http://freefile.kristopherw.us/index.php?showpage=register]here[/url] if you haven't used Freefile before.)

Download:
http://freefile.kristopherw.us/uploads/kristopherwindsor/kpaste-tool.zip

This program is made with Chisock:
[code]' KPaste Utility! v1.0
' (C) 2008 Innova and Kristopher Windsor

#libpath "chisock/bin/win32"
#include "chisock/Chisock.bi"
#include "windows.bi"

#undef error
#define error() beep(): beep(): system()

#undef escape

Function get_clipboard () As String
  Dim As Zstring Ptr s_ptr
  Dim As HANDLE hglb
  Dim As String s = ""

  If (IsClipboardFormatAvailable(CF_TEXT) = 0) Then Return ""

  If OpenClipboard( NULL ) <> 0 Then
    hglb = GetClipboardData(cf_text)
    s_ptr = GlobalLock(hglb)
    If (s_ptr <> NULL) Then
      s = *s_ptr
      GlobalUnlock(hglb)
    End If
    CloseClipboard()
  End If

  Return s
End Function

Sub set_clipboard (Byref x As String)
  Dim As HANDLE hText = NULL
  Dim As Ubyte Ptr clipmem = NULL
  Dim As Integer n = Len(x)

  If n > 0 Then
    hText = GlobalAlloc(GMEM_MOVEABLE Or GMEM_DDESHARE, n + 1)
    Sleep 15
    If (hText) Then
      clipmem = GlobalLock(hText)
      If clipmem Then
        CopyMemory(clipmem, Strptr(x), n)
      Else
        hText = NULL
      End If
      If GlobalUnlock(hText) Then
        hText = NULL
      End If
    End If
    If (hText) Then
      If OpenClipboard(NULL) Then
        Sleep 15
        If EmptyClipboard() Then
          Sleep 15
          If SetClipboardData(CF_TEXT, hText) Then
            Sleep 15
          End If
        End If
        CloseClipboard()
      End If
    End If
  End If
End Sub

Function escape (Byref text As String) As String
  Dim As String r
  
  For i As Integer = 1 To Len(text)
    Select Case Mid(text, i, 1)
    Case " ": r += "%20"
    Case "$": r += "%24"
    Case "&": r += "%26"
    Case "+": r += "%2B"
    Case ",": r += "%2C"
    Case "/": r += "%2F"
    Case ":": r += "%3A"
    Case ";": r += "%3B"
    Case "=": r += "%3D"
    Case "?": r += "%3F"
    Case "@": r += "%40"
    Case "#": r += "%23"
    Case "%": r += "%25"
    Case Else: r += Mid(text, i, 1)
    End Select
  Next i
  
  Return r
End Function

Dim As Integer a, b
Dim As String l_name, l_pass, pastetext, html
Dim As chi.socket my_socket

If Open("kpaste.txt" For Input As #1) Then
  'get login info and save to file
  Screenres 640, 480, 32
  Print "Enter your KPaste / Freefile login info..."
  Line Input "Name: ", l_name
  Line Input "Pass: ", l_pass
  
  Open "kpaste.txt" For Output As #1
  Print #1, l_name
  Print #1, l_pass
  Close #1
Else
  Line Input #1, l_name
  Line Input #1, l_pass
  Close #1
End If

pastetext = escape(get_clipboard())

If my_socket.client("freefile.kristopherw.us", 80) Or Len(pastetext) = 0 Then Error()

my_socket.put_HTTP_request("freefile.kristopherw.us/index.php?action=paste", "POST", _
"name=" & l_name & "&password=" & l_pass & "&pastename=paste/" & Int(Timer) & "&paste=" & pastetext)

html = my_socket.get_until("")

a = Instr(html, "Pasted: ")
If a = 0 Then Error()
a = Instr(a + 1, html, Chr(34))
b = Instr(a + 1, html, Chr(34))

set_clipboard("http://freefile.kristopherw.us/" & Mid(html, a + 1, b - a - 1))

Beep[/code]

Example paste: